Telefonszámunk: 30-905-2076

A BYROW függvény – soronkénti számítás tömbben gondolkodva

2026-10-23 - horvimi - Kategória: Függvények, Tömbképletek
Hivatkozott Excel verzio: Office365

Sokszor találkozunk olyan feladattal, amikor egy táblázat minden sorára ugyanazt a számítást kell elvégezni, majd az eredményeket egy további kalkulációval kell feldolgozni. A hagyományos megoldásokban eddig ehhez egy képletet írtunk egy új oszlopba, amit lemásoltunk a tartomány aljáig, majd egy másik cellában dolgoztuk fel az eredmény oszlopot. A BYROW függvény pontosan erre kínál egy kompaktabb megoldást. Egyszerűbbnek nem nevezném, de ha nekifogsz ennek az anyagnak, nagy lépést teszel a „Modern Excel” világa felé.

Mit értünk „Modern Excel” alatt?

A Modern Excel nem külön program, hanem egy szemlélet: ugyanazt az Excelt használjuk, de másképp építjük fel a megoldásokat, mint tíz éve. Ezek az újdonságok:

  • Dinamikus tömbök: egyetlen képlet egy egész eredménytartományt ad vissza, ami magától kiömlik (pl. SZŰRŐ, RENDEZ, EGYEDI)
  • XKERES (XLOOKUP): egyszerűbb keresés, mint a FKERES vagy az INDEX-HOL.VAN
  • LET és LAMBDA: olvashatóbb képletek, és saját függvények makró nélkül
  • Új tömbfüggvények: BYROW, MAP, VSTACK, TEXTSPLIT és társaik, segédoszlop helyett
  • Power Query: az adatok tisztítása és átalakítása újrafuttatható lépésekben
  • Adatmodell és Power Pivot: több tábla összekapcsolása, DAX mértékek
  • Táblázatok: a tartomány magától nő, a képletek olvashatók

A közös szál: kevesebb kézi munka és kevesebb segédoszlop, és a megoldás akkor is működik tovább, ha jövő hónapban újabb adat érkezik.

Mit tud a BYROW?

A BYROW egy tömbfüggvény, amely egy megadott tartomány vagy tömb minden sorára alkalmaz egy kalkulációt, és egy tömböt ad vissza a soronkénti eredményekkel.

Eddig még nem kapott magyar nevet, így a magyar verzióban is BYROW néven találod meg. Egyelőre ez van.

A lényeg, hogy nem kell egy képletet lehúznunk mint régen, egyetlen képlet elég, amely automatikusan végigfut a teljes tartományon.

Általános szintaktika

=BYROW(tömb;összesítő_függvény)
  • tömb: A feldolgozandó tartomány vagy tömb.
  • függvény: Egy összesítés, ami megadja, hogy mit csináljunk minden sorral. Lényeges, hogy egy értéket adjon soronként, de hát ettől lesz összesítés.
    Ha a beépített függvények egyike sem alkalmas, akkor készíthetsz egy saját LAMBDA függvényt is a BYROW-n belül.
    ByRow-fuggvenyeiBYROW-fuggvenyei-tablazat

Egy egyszerű példa

Tegyük fel, hogy a B2:D4 tartományban januártól márciusig három termék három havi forgalmi adatai vannak, és soronként szeretnénk megkapni az átlagot. Hagyományos megoldással nagyon egyszerű dolgunk van. Az eredmény oszlop első cellájába kiszámoljuk az első sor átlagát, majd lehúzzuk a többi sorra.

byrow-abra-hagyomanyos


byrow-abra-byrow

Hogy működik?

Nagy a felelősségem, hogy le tudom-e írni szövegesen. A videóban van egy animáció, ami támogatja ezt a magyarázatot.

=BYROW(B2:D4;ÁTLAG)

A képlet az E2-be kerül.

  1. Megnézi, hogy hány sora van az első paraméterben kapott tartománynak
  2. Indít egy ciklust és végigmegy a tartomány minden során. Minden cikluskörben az aktuális sor (3 cella) adatait átlagolja, és az eredményt eltárolja egy egyelőre még nem látható, virtuális tömb aktuális elemében.
  3. Minden cikluskörben hozzáíródik egy új átlagérték a tömbhöz.
  4. Miután minden sort feldolgozott, a virtuális tömböt kibontja (kiönti) az E2-től lefelé.

Tehát egyetlen képletben végigfut minden soron, és soronként adja vissza az átlagot egy függőleges tömbben.

Ejha, ennek aztán sok értelme van. Az ÁTLAG lehúzását legalább értem.

Igazad van, ha ez jár a fejedben. Ennél a konkrét példánál nekem sem a tömbképlet jutna elsőre eszembe, bár azért már itt is tudok előnyét mondani:

  • A keletkező eredmény egy és oszthatatlan, nem lehet belőle törölni
  • Nem lehet egyik tagját sem megváltoztatni másik képletre vagy valami konstansra. (Ezt akár hátrányként is említhetném de csak csendben)

Mikor jobb a BYROW, mint a lehúzott képlet?

Az előző példánál a lehúzott ÁTLAG képlet ugyanolyan jó, sőt egyszerűbb is. A BYROW akkor kezd igazán értéket adni, amikor a soronkénti eredményre nincs szükségünk külön oszlopban, hanem egy másik számítás bemeneteként kell. Két példa ugyanarra az adatsorra: a B2:D10 tartományban három hónap értékesítési adatai vannak, az A oszlopban a termékek nevei.

1. példa: Hány termék érte el minden hónapban a 100-as célt?

Könnyű belátni, hogy ha a legkisebb érték is nagyobb vagy egyenlő mint 100, akkor a cél teljesült.

Hagyományos megoldás

Ha meg akarjuk számolni, hogy hány ilyen sor van, akkor ehhez kell egy segédoszlop az E2 cellától. Ha a cél teljesül, akkor 1, különben 0.

=HA(MIN(B2:D2)>=100;1;0)

Ezt le kell húzni a tábla aljáig, majd egy külön cellában összeadni az eredményeket. A SZUM csak az egyeseket fogja összeadni, ezáltal megszámlálást végez.

=SZUM(E2:E10)

byrow-pelda--SZUM-hagyomanyos


Modern megoldás – BYROW

BYROW-val ugyanez egyetlen cellában megoldható, segédoszlop nélkül:

byrow-pelda-SZUM-modern

=SZUM(HA(BYROW(B2:D10;MIN)>=100;1;0))

Soronként megnézi, hogy a legkisebb érték eléri-e a célt, és összerak egy 1/0 -ból álló tömböt, amit átad a SZUM függvénynek. A SZUM a hagyományos megoldáshoz hasonlóan csak az 1-eket adja össze, azaz megszámol.

2. példa: Melyek ezek a termékek?

Hagyományos megoldás

BYROW nélkül nem igazán tudjuk ezt régi módszerrel képlettel megoldani, vagy esetleg valami iszonyú bonyolult tömbkifejezést kell keresnünk. De ha egyszerűen rászűrünk az előző példa hagyományos megoldása után az E oszlopban az 1-ekre, akkor kész is vagyunk, kimásolhatjuk valahová.

Modern megoldás – BYROW

A SZŰRŐ tömbfüggvénnyel ez is simán megoldható. Erről a függvényről már írtam a megjelenésekor.

byrow-pelda-Szuro
=SZŰRŐ(A2:A10;BYROW(B2:D10;LAMBDA(sor;MIN(sor)>=100)))

A BYROW soronként IGAZ vagy HAMIS értéket ad vissza, a SZŰRŐ pedig ennek alapján válogatja ki a termékneveket. Az eredmény magától kiömlik a cella alatti részre.

Mikor kell a LAMBDA?

LAMBDA akkor kell, ha nincs a feladatra kész beépített összesítő függvény, és saját számítást kell írnunk soronként. Az ingadozást, azaz a sor legnagyobb és legkisebb értékének különbségét például egyetlen függvény sem adja vissza. Erre épül a következő példa. Most hat hónap értékesítési adata van a B2:G9 tartományban, a H oszlopban sparkline diagramok mutatják a trendet.

Hagyományos megoldás

Hagyományosan az I2 cellába egy egyszerű kivonás képletet írunk, és lehúzzuk I9-ig.

byrow-pelda-ingadozas-hagyomanyos

=MAX(B2:G2)-MIN(B2:G2)

Modern megoldás BYROW és LAMBDA függvényekkel

=BYROW(B2:G9;LAMBDA(sor;MAX(sor)-MIN(sor)))

byrow-pelda-ingadozas-lambda-byrow

Mire idáig elértél, remélem már érted a BYROW működését. Viszont a LAMBDA felvethet pár kédőjelet, ha eddig nem ismerted. Ha esetleg érdekel, szeretettel ajánlom figyíelmedbe a LAMBDA függvényről írt bejegyzéseimet. Az alap leírást itt találod

Az I2-be írt formula egy ciklust futtat a B2:G9 táblázat sorain, ahogy eddig is.  Minden cikluskörben az aktuális sort beteszi egy sor nevű változóba, és átadja a LAMBDA függvénynek, ami kiszámolja a sorban lévő legnagyobb és legkisebb érték különbségét. A minden sorban így kiszámolt értékek képezik a kibomló tömböt.

Táblázat forrás

Mivel nagy kebelbarátom a táblázat funkció az Excelben, most is megemlékezek róla. Remélem te is látod, hogy ha a feldolgozandó tartományt táblázattá alakítod, akkor használhatsz a képletekben tábázat hivatkozásokat, így az adatforrás mérete dinamikusan nőhet, a képletekhez nem kell hozzányúlni.

Letölthető demo mukafüzet

ByRow-bemutató-munkafüzet