A professzionális Excel felhasználók gyakran dolgoznak névtartományokkal. Ez ugyebár azt jelenti, hogy egy tartományt elnevezünk, és a képletekben a tartomány címe helyett a nevét használjuk. A tartományok elnevezését a szerkesztőléc bal oldalán lévő Név mezőben vagy a Képletek szalagon található Névkezelőben lehet megadni. A Dinamikus névtartományokról olvashatsz […]
Tovább... →Tartományok Kezelése
Egy korábbi anyagban arról volt szó, hogy ha lehetséges, kerüljük a cella egyesítést (Merge Cells), és helyette inkább a kijelölés közepére igazítást (Center Across Selection) használjuk.
Mivel ennek a menüpontnak az elérése több kattintást igényel, így érdemes lehet a PERSONAL makrómunkafüzetbe tenni egy olyan makrót, ami elvégzi az igazítást.
Az egyéni makró munkafüzet (PERSONAL.XLS(B)
Az egyéni makró munkafüzetről egy külön oktatóanyagban van szó. Röviden, ez egy olyan speciális makrófájl, ami ha létezik, akkor az Excel indításakor automatikusan megnyílik, de rejtett ablakban. A benne lévő makrók pedig láthatóvá, használhatóvá válnak. Kisebb segéd makrókat szoktunk bele tenni, amik felgyorsítanak egyes műveleteket, és hagyományos módon csak körülményesen tudnánk megcsinálni. Ilyen például egy cella tartalmának a kijelölés közepére igazítása.
Lépjünk át a Visual Basic Editor felületére (ALT+F11)
Ha nem látszódik, Kapcsoljuk be a Project Explorer ablakot (Ctrl+R). Ha még nem létezik a PERSONAL makrófüzet, akkor létre kell hozni az említett tutorial alapján.
A PERSONAL makrófüzetbe illesszük be a következő kódot.
[vb]
Sub WrapAcross()
With Selection
.HorizontalAlignment = xlCenterAcrossSelection
.VerticalAlignment = xlCenter
.WrapText = True
.Orientation = 0
.ShrinkToFit = False
.MergeCells = False
End With
End Sub
[/vb]
Használata
- Egy cellába beírjuk a szöveget, majd kijelöljük azt a tartományt, amin belül középre szeretnénk igazítani.
- Lefuttatjuk a makrót. Rendelhetünk hozzá billentyűkombinációt, vagy gyors elérési eszköztár gombot is . Nem egyesíti a cellákat, mégis középen látszik.
Az egész folyamatot megtekinthetjük a VIDEÓ anyagban
Igazítás a kijelölés közepére makróval
Gyakori feladat, hogy egy szűrt táblázatban az egyik oszlopban az adatokat teljesen vagy részben másikra szeretnénk cserélni. Ezt kézi szerkesztéssel nagyon egyszerű megtenni, de ha a feladatot makró kódon belül szeretnénk megoldani (mert pl. egy nagyobb feladat része), akkor már nem annyira egyértelmű a helyzet.
Volt már egy korábbi anyag arról, hogy ha szűrt tartományba szeretnénk a vágólapról beilleszteni adatokat, de most nem erről van szó, hanem egyszerű felülírásról.
Kézi módszer
Ez nagyon egyszerű, hiszen már jópár verzió óta az Excel kiválóan kezeli ezt a problémát.
- Leszűrjük a táblát
- A módosítandó oszlopban az első elemet átírjuk
- Lehúzzuk az aljáig
Ha megszüntetjük a szűrést, akkor látni fogjuk, hogy csak az előzőleg szűrt adatok módosultak, a közbensők, amik a szűréskor rejtve voltak, nem változtak.
Makró – VBA módszer
Ha az előző műveletsort rögzítjük makróval, akkor a kódból nagyon gyorsan kiderül, hogy általánosan nem használható, tehát változó adattartalom esetén, ahol a szűrés más-más eredményt adna. Emiatt ezt a problémát kicsit komolyabban kell leprogramozni.
Elméleti háttér
Ha egy oszlop szűrt adatokat mutat, és abban módosítani szeretnénk, akkor előbb ki kell jelölni CSAK a látható cellákat.
- Kijelöljük a teljes, szűrt táblázatot (Ctl-A)
- Speciális kijelölés -> Csak a látható cellák
Így viszont az oszlopban lévő adatok szétválnak egymástól, és ha újra kinyitjuk, azaz megszüntetjük a szűrést, akkor több, nem összefüggő tartományt fogunk látni.
Tehát a makróval a kategória oszlopban lévő, látható tartományokat kell módosítani. Példánkban a „Beverages” szót, másik kategória névvel.
A Selection objektum
Ha több, nem összefüggő tartományt jelölünk ki, vagy hozunk létre a fenti módszerrel, attól az még a SELECTION objektummal lefedhető, és egy lépésben átírható a benne lévő összes cella értéke.
A Fejléc problémája
Mivel előre nem tudjuk, hogy milyen sorok fognak beleesni a szűrésbe, legegyszerűbb, ha a fejlécet is belevesszük a kijelölésbe. Viszont így annak az értéke is felülíródik. Ezt úgy oldjuk meg, hogy a felülírás előtt elmentjük a fejléc eredeti értékét, majd a végén visszaírjuk.
A VBA kód
A példában egy általánosabb megoldást adok, ahol a subrutin argumentumként kapja meg azt, hogy melyik oszlopban kell dolgoznia, és mire kell cserélni a szűrt elemeket.
[vb]
Sub Replace_filtered_data(header_cell As Range, new_value As Variant)
Dim h As Variant
‘A fejléc tartalmának megjegyzése
h = header_cell.Value
‘A módosítandó oszlop kijelölése fejléccel együtt
Range(header_cell, header_cell.End(xlDown)).Select
‘Látható cellák kijelölése
Selection.SpecialCells(xlCellTypeVisible).Select
‘A létrejött, nem összefüggő tartomány feltöltése az új adattal
Selection.Value = new_value
‘A fejléc visszaírása
header_cell.Value = h
End Sub
Sub proba()
Call Replace_filtered_data(ActiveCell, Range("csere"))
End Sub
[/vb]
Letölthető gyakorló munkafüzet: szurt_tartomany_modositasa
Az egészet működés közben, magyarázattal együtt láthatod a videóban
Szűrt adatok módosítása makróval
Gyakran felmerül az igény, hogy egy munkalapon a képleteket tartalmazó oszlopokat értékké alakítsuk. Ennek több oka is lehet:
- Nem szeretnénk, hogy lássák a képleteket
- Az értékké alakítással gyorsítjuk a működést, mert az Excel-nek nem kell állandóan újraszámolni a képleteket
A probléma
A másolás / érték beillesztés műveletet mindenki ismeri. A baj az vele, hogy csak egy, összefüggő tartományban működik. Hiába jelölünk ki több tartományt pl. a Ctrl lenyomása mellett. A másolás is csak akkor működik, ha azonos a kijelölt területek sorainak a száma. De saját magára értékként nem lehet beilleszteni két egymással nem összefüggő területet.
A megoldás
A megoldás egy pár soros makró, ami kijelöli a képleteket tartalmazó cellákat (sorokat/oszlopokat), majd egy ciklussal végiglépked a kijelöléskor képződött területeken, és mindegyiket értékké alakítja.
[vb]
Sub keplet_helyett_ertek()
Range("a1").Select
‘Képleteket tartalmazó tartományok kijelölése
Selection.SpecialCells(xlCellTypeFormulas, 23).Select
‘A keletkezett területek bejárása és képlet-érték csere
For Each akt_range In Selection.Areas
akt_range.Formula = akt_range.Value
Next
End Sub
[/vb]
A fenti makrót másoljuk egy makró-munkafüzet egyik moduljába, vagy a Personal (Egyéni) makró munkafüzet ,megfelelő moduljába, és máris kipróbálhatjuk.
A kapcsolódó videóban láthatjuk a folyamatot és a működést is. Ezen kívül mi van még a videóban?
- Speciális kijelölés lehetőségei
- Képleteket tartalmazó cellák kijelölése
- Egyéni makró munkafüzet létrehozása (ha még nincs)
- Makró elhelyezése az egyéni makró munkafüzetben
- Eszköztár gomb rendelése a makróhoz
A makrófejlesztés egyik fontos része a „Bolond állóság” (FoolProof) biztosítása. Emiatt egy igényesebb VBA kód hibaellenőrzéseket is tartalmaz.
Az egyik ilyen eset lehet, hogy ellenőrizzük, az aktív cella egy korábban már táblázattá (Lista) alakított tartományban van-e?
Íme egy erre szolgáló függvény
[vb]
Function in_table() As String
Dim tname As String
tname = ""
On Error Resume Next
tname = ActiveCell.ListObject.Name
in_table = tname
End Function
[/vb]
Úgy működik, hogy ha az aktív cella benne áll egy táblázatban (listában), akkor létezik a .name tulajdonsága. Különben hibát ad, amit kezelünk.
A függvény a táblázat nevét, vagy üres stringet ad vissza.
Tovább... →Az előző részben azt mutattam meg, hogy hogyan lehet egy szűrt, azaz rejtett sorokat is tartalmazó tartományba adatokat beilleszteni makró használata nélkül.
Arra jutottunk, hogy ez csak akkor lehetséges, és úgy sem egyszerűen, ha ugyanazon szűrt táblázat egyik oszlopából szeretnénk másolni adatokat egy másik oszlopba. Mivel egy táblában vannak garantált, hogy a szűrés hatására mindkét oszlopban ugyanazok a sorok leszek rejtve.
A példában a szűrés után a C oszlop adatait másoljuk a B oszlopba.
De mi van akkor, ha a másolandó és a céltartomány nem ugyanabban a táblázatban van?
Esetleg másik lapon, ami akár nem is szűrt?
Ez esetben makrót kell használni. Szerencsétek van, mert elkészítettem, és itt közzéteszem a programot. Futtatáskor csak ki kell jelölni a forrás tartományt, majd a céltartomány első celláját, és a többit rábízni a makróra.
A makró használatát és működését Videóban is megmutatom.
A makró kódja
[vb]
‘Beillesztés szűrt tartományba, 1 oszlopos megoldás
‘A forrástartományt ki kell jelölni, a Céltartománynak csak a kezdőcelláját kell megadni
‘A céltartomány legyen/lehet szűrt oszlopban
‘Az átmásolás értékként történik
Sub Paste2VisRows2()
Dim rFrom As Range, rTo As Range
Dim i As Long, Ofset As Long
Set rFrom = Application.InputBox(Prompt:="Please select copy area", Title:="Area Selection", Type:=8)
Set rTo = Application.InputBox(Prompt:="Please select the first cell of paste area", Title:="Area Selection", Type:=8)
If rFrom.Columns.Count > 1 Or rTo.Columns.Count > 1 Then
MsgBox "Both source and destination ranges must be one column wide!"
Exit Sub
End If
If rTo.Cells.Count <> 1 Then
MsgBox "Select only one cell as the beginning of the paste area!"
Exit Sub
End If
Application.ScreenUpdating = False
Ofset = 0
For i = 1 To rFrom.Rows.Count
If Not rFrom.Rows(i).Hidden Then
Do Until Not rTo.Offset(Ofset).EntireRow.Hidden
Ofset = Ofset + 1
Loop
rFrom.Cells(i).Copy
rTo.Offset(Ofset).PasteSpecial xlPasteValues ‘Átmásolja az aktuális cellát a forráshelyről a célhelyre
Ofset = Ofset + 1
End If
Next i
Application.ScreenUpdating = True
End Sub
[/vb]
Letölthető munkafüzet: beillesztes-szurt-tartomanyba
Másolás szűrt tartományba makróval
Ha egy tartományban képlettel számolunk, akkor nem tudunk visszaadni üres cellát. Leggyakrabban nullát, vagy üres stringet adunk vissza, amit az Excel másképp kezel bizonyos esetekben, mint az üres cellát.
A példában, ha az A1-ben nulla van, akkor üres stringet, különben 1-et adunk vissza:
=IF(A1=0,"",1)
Tegyük fel, hogy ez a képlet sok soron keresztül megy, és a végén grafikont kell belőle rajzolni. A problémát az okozza, hoyg az Excel grafikon motorja csak a valóban üres cellákat tekinti annak, és azokat nem rajzolja ki a diagramra, de az üres stringet nullának tekinti, és kirajzolja.
Egyik megoldás az lehet, hogy a módosítjuk a képletet, és az üres string helyett hibát adunk, amit szintén figyelmen kívül hagy a grafikon.
=IF(A1=0,NA(),1)
Másik lehetőség, hogy kijelöljük az oszlopot, sé egy kis makróval töröljük az összes üres stringet tartalmazó cella tartalmát.
Üres stringeket tartalmazó cellák kiürítése VBA kóddal
[vb]
‘A kijeloles cellái közül törli a tartalmat, ha üres stringet talál benne
Sub delete_empty_strings()
Dim u As Range
Dim cur As Range
For Each cur In Selection.Cells
If cur.Value = "" Then cur.ClearContents
Next
End Sub
[/vb]
Ha Excelben egy számtartomány minden értékét szeretnénk szorozni egy adott konstans értékkel, akkor a következő lehetőségeink vannak:
- Egy segédoszlopban mellette elvégezzük a számítást, majd értékként visszatesszük az eredményt az eredetire
- Speciális vágólap beillesztéssel, szorzás műveletet választva
- Alkalmazzuk a következő makrót, ami a bekért számmal szorozza az előzőleg kijelölt tartomány számait.
[vb]
Sub multiply_range()
‘A kijelölt tartomány számait szorozza az Inputbox-ban megadott számmal
a = InputBox("value to multiply with:")
Selection.Value = Evaluate(Selection.Address & "*" & a)
End Sub
[/vb]
Mindez hogy működik, és hogy kell használni?
Kiderül a kapcsolódó videóból
Letölthető munkafüzet: tartomány-szorzas-konstanssal
Tartomány szorzása konstanssal
Ha csak egy darab összefüggő tartományra szeretnénk a képleteket értékükkel helyettesíteni, akkor azt viszonylag gyorsan meg tudjuk csinálni az EXCEL által adott speciális beillesztési lehetőséggel.
De mi van akkor, ha egy munkalapon az összes képletet ki szeretnénk cserélni értékre? Hagyományos módszerrel egyenként kell megcsinálni. De ha az alábbi kis kódot elraktározzuk magunknak pl. a PERSONAL makrófüzetbe, akkor bármelyik dokumentumunknál nagyon gyorsan megtehetjük a cserét.
Háttér
Az Excel a speciális kijelölések segítségével megadja a módját, hogy az összes, képletet tartalmazó cellát egy lépésben kijelöljük. Ezt az Excel felületen így kell:
- F5
- Special… (Irányított…) gomb
- Képletek
Ugyanezt VBA kóddal
Selection.SpecialCells(xlCellTypeFormulas, 23).Select
Képletek cseréje nem összefüggő tartományoknál
Nagyon valószínű, hogy nem csak egy tartományban lesznek képletek. Így több, nem összefüggő tartományt jelöl ki az Excel. Ezekre viszont NEM LEHET értéket beilleszteni az Excel felületről.
Megoldás
A nem összefüggő tartományokat egy VBA ciklusban bejárva, egyesével cseréljük ki bennük a képleteket értékre.
A nem összefüggő tartományok bejárásának leírását lásd itt.
[vb]
‘Képletek értékké alakítása nem összefüggő tartományokban is
Sub Formula2Value()
Dim r As Range
‘Képleteket tartalmazó cellák(tartományok) kijelölése
Selection.SpecialCells(xlCellTypeFormulas, 23).Select
‘A keletkezett tartományok (areas) bejárása
For Each r In Selection.Areas
r.Select
Selection.Formula = Selection.Value
Next
End Sub
[/vb]
Tovább... →Az Excel használata közben többféleképpen keletkezhetnek nem összefüggő tartományok:
- Mi jelöljük ki a Ctrl billentyűvel
- Szűréssel keletkeznek
- Speciális kijelölést használunk, pl.: Az összes képletet tartalmazó cella kijelölése
- VBA kódból jelölünk ki nem összefüggően (lásd itt)
- Egyéb ?
Akármilyen módon is keletkeztek a tartományok, a kezelésük már nem annyira egyszerű, sőt, bizonyos műveletek nem megengedettek ilyen kijelöléskor. Például nem lehet beilleszteni értékeket a vágólapról.
Elméleti háttér
Ha több tartományt jelölünk ki, akkor a kijelölésen (Selection) belül létrejön egy új kollekció „AREAS” (területek) néven. Próbáljuk ki, hogy kijelölünk néhány nem összefüggő tartományt CTRL lenyomásával, majd az Immedate ablakba beirjuk:
?Selection.areas.count
Válaszként megkapjuk, hogy hány tartományt jelöltünk ki. A képen látható, hogy három tartomány kijelölése után milyen választ kaptunk.
A gyűjtemény egyes területeire a SELECTION.AREAS(n) módon lehet hivatkozni.
A területek (areas) bejárása
Mivel ez is egy kollekció, a bejárásához legegyszerűbben egy for each ciklust lehet használni. A példában a kijelölt területek celláinak a számát írjuk ki egy üzenőboxba. A kód futtatása előtt legyen kijelölve legalább kettő, de jobb, ha több tartomány.
[vb]
Sub areas()
Dim r As Range
‘A keletkezett tartományok (areas) bejárása
For Each r In Selection.Areas
r.Select
msgbox selection.cells.count
Next
End Sub
[/vb]
Tovább... →